【Access VBA】「マウス追随ボタン」と「逃げて押下できないボタン」をMouseMoveイベントで作る

世の中のAccessユーザーの皆さんは、真面目に実用的な業務アプリケーションの開発に勤しんでいることだと思います。

そんな未来を憂いた私が、今回はAccess VBAを使って、「マウスの動きに追随して移動するコマンドボタン」と「押下しようとすると逃げて押せないコマンドボタン」を実装するVBAのサンプルプログラムを紹介します。

Accessユーザーの誰もこのような需要は無いかと思いますが、一般的なAccessアプリケーションではあまり使われない「MouseMove」イベントと「Timer」イベントの簡単な解説もしていくので、そこも踏まえて御一読ください。
 
 

実際の動作サンプル

今回のサンプルプログラムでは、実際の動作を動画で確認していただいた方がイメージし易いかと思います。
最近Twitterの当ブログアカウント内で、「マウスの動きに追随して移動するコマンドボタン」の動画を紹介していますので、良ければそちらも確認してみてください。

今日も忙しい仕事の合間をぬって、まったく役に立たない、Access VBAを書きました😁

コマンドボタンがマウスの動きに追随して移動します

OnMouseイベントとTimerイベントで作りましたが、この処理が役に立つシチュエーションが思いつきません…

何か無いですかねぇ🤔 pic.twitter.com/UVL8lLPZmv

— ITエンジニアの備忘録的技術ブログ【仮】のなかの人 (@DepthbombM) April 15, 2021

「マウスの動きに追随して移動するコマンドボタン」の紹介

当項では、前項で動画でも掲載した「マウスの動きに追随して移動するコマンドボタン」を紹介していきます。

サンプルプログラム実装用フォーム例

今回紹介するサンプルプログラムでは、VBE内にコピペしてもらえれば動くように作ってありますが、その為には以下のコントロールを設置してください。

「マウスの動きに追随して移動するコマンドボタン(Timer有り)」サンプルプログラム

当項では「逃げて押下できないボタン」のサンプルプログラムを紹介します。
当サンプルプログラムでは「MouseMoveイベント」とともに「Timerイベント」も併せて使用します。

前項で作成したフォームのVBAのコードに以下の処理を丸っと貼り付けてください。

Option Compare Database
Option Explicit


Dim MoveLeftPosition As Long    'ボタンの座標(Y)を格納します。
Dim MoveTopPosition As Long     'ボタンの座標(X)を格納します。
Dim HalfWidth As Long           'ボタンの幅の半分の長さを格納します。
Dim HalfHeight As Long          'ボタンの高さの半分の長さを格納します。

Private Sub btn_test_Click()

    'クリックされたらTimerを停止して自フォームを閉じます。
    Me.TimerInterval = 0
    DoCmd.Close acForm, Me.Name

End Sub

Private Sub btn_test_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

    'Timerイベント開始※1ミリ秒
    Me.TimerInterval = 1

End Sub

Private Sub Form_Load()

    'ボタンコントロールの中心の幅と高さを取得します。
    HalfWidth = Round(Me.btn_test.Width / 2, 0)
    HalfHeight = Round(Me.btn_test.Height / 2, 0)

End Sub

Private Sub Form_Timer()

    'ボタンコントロールの座標を指定します。
    Me.btn_test.Left = MoveLeftPosition
    Me.btn_test.Top = MoveTopPosition

End Sub

Private Sub 詳細_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

    'マウスの座標を元に、ボタン幅や高さを考慮して変数に格納します。
    MoveLeftPosition = X - HalfWidth
    MoveTopPosition = Y - HalfHeight

End Sub

サンプルプログラム解説

「マウスの動きに追随して移動するコマンドボタン(Timer無し)」サンプルプログラム

前述したサンプルプログラムでは、Timerイベントを使用しましたが、実はTimerイベントは使わなくても、マウスの動きに追随する処理は作れます。
前述のサンプルプログラムでTimerイベントを使用したのは、マウスのポインターがコマンドボタンの上に移動した際に、自動的に追随を開始するようにしたかったからであり、追随を開始するきっかけを別で作れるならTimerイベントは不要です。

当項では、「Timerイベントを使わないパターン」のサンプルプログラムを紹介します。

尚、前述したフォームに対して、当サンプルプログラムでは、更にテキストボックスを一つ追加する必要があります。

Option Compare Database
Option Explicit


Dim HalfWidth As Long         'ボタンの幅の半分の長さを格納します。
Dim HalfHeight As Long        'ボタンの高さの半分の長さを格納します。

'クリック時に、マウス追随を有効化無効化します。
Private Sub btn_test_Click()

    Dim EnableFlag As Integer
    
        EnableFlag = Me.txt_Run.Value

        'MouseMoveイベント制御フラグを有効化、又は無効化します。
        If EnableFlag = 0 Then
            Me.txt_Run.Value = 1
        Else
            Me.txt_Run.Value = 0
        End If

End Sub

Private Sub Form_Load()

    'ボタンコントロールの中心の幅と高さを取得します。
    HalfWidth = Round(Me.btn_test.Width / 2, 0)
    HalfHeight = Round(Me.btn_test.Height / 2, 0)

    'MouseMoveイベント制御フラグを初期化します。
    Me.txt_Run.Value = 0

End Sub

Private Sub 詳細_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

    'MouseMoveイベント制御フラグが0なら処理をしない。
    If Me.txt_Run.Value = 1 Then
        
        'ボタン幅や高さを考慮してボタン位置の座標を指定します。
        Me.btn_test.Left = X - HalfWidth
        Me.btn_test.Top = Y - HalfHeight
    End If

End Sub

サンプルプログラム解説

「押下しようとすると逃げて押せないコマンドボタン」の紹介

当項では、「押下しようとすると逃げて押せないコマンドボタン」を紹介していきます。
尚、ボタンは押すためにあるので、押せないボタンに存在意義はありません。
 
 

サンプルプログラム実装用フォーム例

今回紹介するサンプルプログラムでは、VBE内にコピペしてもらえれば動くように作ってありますが、その為には以下のコントロールを設置してください。

「押下しようとすると逃げて押せないコマンドボタン」サンプルプログラム

当項では「逃げて押下できないボタン」のサンプルプログラムを紹介します。
前項で作成したフォームのVBAのコードに以下の処理を丸っと貼り付けてください。

Option Compare Database
Option Explicit


Dim IniLeft As Long         'コマンドボタン初期Left
Dim IniTop As Long          'コマンドボタン初期Top
Dim FormWidth As Long       'フォーム幅
Dim FormHeight As Long      'フォーム高さ

Const MoveLength As Long = 2000     '移動時の長さ

Private Sub btn_test_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

    'ランダムな値によって移動先を判別します。
    Select Case Get_RandomDirection()
    
        Case 1
            If Not Is_OutOfFormSize(1) Then
                Me.btn_test.Left = Me.btn_test.Left + MoveLength
            End If
        Case 2
            If Not Is_OutOfFormSize(2) Then
                Me.btn_test.Top = Me.btn_test.Top + MoveLength
            End If
        Case 3
            If Not Is_OutOfFormSize(3) Then
                Me.btn_test.Left = Me.btn_test.Left - MoveLength
            End If
        Case 4
            If Not Is_OutOfFormSize(4) Then
                Me.btn_test.Top = Me.btn_test.Top - MoveLength
            End If
    End Select

End Sub

Private Sub Form_Load()

    'コマンドボタンの初期位置を取得します。
    IniLeft = Me.btn_test.Left
    IniTop = Me.btn_test.Top

    'フォームの幅と高さを取得します。
    FormWidth = Me.Width
    FormHeight = Me.詳細.Height

End Sub

Private Sub 詳細_Click()

    '移動したボタンを元に位置に戻します。
    Me.btn_test.Left = IniLeft
    Me.btn_test.Top = IniTop

End Sub

'1から4までの数値をランダムに返します。
Function Get_RandomDirection() As Integer

    '乱数を初期化
    Randomize
    '1から4までのランダムな値を戻り値にセットします。
    Get_RandomDirection = Int(4 * Rnd + 1)

End Function

'移動先がフォームのサイズの範囲外かを返します。
Function Is_OutOfFormSize(MoveType As Integer) As Boolean

    Is_OutOfFormSize = False

    Select Case MoveType
        Case 1
            If FormWidth < Me.btn_test.Left + MoveLength Then
                Is_OutOfFormSize = True
            End If
        Case 2
            If FormHeight < Me.btn_test.Top + MoveLength Then
                Is_OutOfFormSize = True
            End If
        Case 3
            If 0 > Me.btn_test.Left - MoveLength Then
                Is_OutOfFormSize = True
            End If
        Case 4
            If 0 > Me.btn_test.Top - MoveLength Then
                Is_OutOfFormSize = True
            End If
    End Select

End Function

サンプルプログラム解説

【おまけ】「MouseMoveイベント」と「Timerイベント」の簡単な解説

今回の記事では、普段あまり使われることのない、Access VBAの「MouseMoveイベント」と「Timerイベント」を簡単に解説しておきます。
 
 

MouseMoveイベント

MouseMoveイベントは、Accessのフォームのデザイナー画面でプロパティを表示した際に、イベント欄のなかの「マウス移動時」です。

「マウス移動時」のイベントを有効にすると、VBAのコードに以下の行が追加されます。

Private Sub コントロール名_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

引数が四つもあり独特です。
まずはこの引数の意味を紹介します。

詳しくはMicrosoft公式ドキュメントをご参照ください。
Microsoft Office VBAリファレンス -Access Formオブジェクト MouseMoveイベント-
 
 

Timerイベント

「Timerイベント」は、Accessのフォームのデザイナー画面でプロパティを表示した際に、イベント欄のなかの「タイマー時」です。

「タイマー時」のイベントを有効にすると、VBAのコードに以下の行が追加されます。

Private Sub Form_Timer()

このイベントのプロシージャに処理を記述すると、指定した実行間隔で繰り返し呼び出されます。
例えば、「特定のフォルダを監視し、指定したファイルが存在していたら、それをトリガーに何らかの処理を実行する」といった処理を実装する場合などによく使われます。

この「Timerイベント」を呼び出す際には、以下の様に記述します。

Me.TimerInterval = 1000

フォームに「TimerInterval」プロパティを指定することでTimerイベントが開始されます。
「TimerInterval」プロパティの値は「ミリ秒」単位なので、例えば1秒間隔で実行させる場合は、上記の様に1000と指定します。

また、「Timerイベント」を停止する場合は以下のように記述します。

Me.TimerInterval = 0

「Timerイベント」の実行間隔を0で指定することで、「Timerイベント」の呼び出しそのものが停止します。

詳しくはMicrosoft公式ドキュメントをご参照ください。
Microsoft Office VBAリファレンス -Access Formオブジェクト Timerイベント-
 
 

最後に

今回は、Access VBAを使用して、「マウスの動きに追随して移動するコマンドボタン」と「押下しようとすると逃げて押せないコマンドボタン」を作成するサンプルプログラムを紹介しました。

これまでのブログの記事では、VBAやVBScriptなどのサンプルプログラムを紹介する場合は、なるべく実用性のあると思われるものを掲載してきました。
自分自身が「何の役に立つのだろうか？」と思った情報を掲載するのは初めての試みです。

今回のサンプルプログラムを利用して、ユーザーの業務を妨害してみたり、同僚を驚かせてみたりするぐらいしか活用する術はありませんが、是非気分転換に実装してみてもらえると嬉しいです。

今回も読んでいただきましてありがとうございました。
それでは皆さまごきげんよう！